The trick

Всем привет, сегодня я хотел бы рассказать как написать простейший VST плагин на ассемблере. Те кто создает музыку на компьютере, или занимается обработкой звука хорошо знакомы с этими плагинами и часто используют их как для генерации звука так и для обработки. Основное достоинство таких плагинов - это простота подключения к большинству аудио или музыкальных редакторов. Существуют два типа плагинов VST эффекты и VST инструменты (которые также называют VSTi). В данной статье мы рассмотрим создание VST эффекта, на основе стандарта VST 2.4 который поддерживают большинство редакторов. Программировать будем на FASM'е.
Итак, для начала нужно определится с самим эффектом и для простоты я решил использовать биткрашер. Суть эффекта состоит в понижении разрешения звука как по частоте так и по амплитуде без всякой фильтрации, что дает характерное звучание из-за шумов квантования. Такой эффект нередко можно встретить в электронной музыке, я и сам его очень часто использую. Наглядно эффект продемонстрирован на рисунке:

Для начала определимся с параметрами эффекта - это частота среза, количество уровней громкости (битность) и дополнительно добавим регулировку выходной громкости. Частота среза у нас может регулироваться от половины частоты дискретизации до нуля, битность от 1 до 16 бит (от 2 до 65536 уровней соответственно), громкость от 0 до 100%. Звук в VST стандарте представляет из себя буффер с семплами, где каждый семпл представлен либо 32-битным числом с плавающей точкой, либо 64 битным числом с плавающей точкой. Частота дискретизации задает количество таких семплов в секунду; максимальная частота которая может быть воспроизведена равна половине частоты дискретизации (обычно 22050Гц). Амплитуда варьируется от -1 до 1, но может также выходить за пределы, что влечет за собой перегруз и клиппинг. Также следует учитывать количество каналов звука, для стерео звука это два канала и каждый обрабатывается независимо. Для того чтобы понизить разрядность звука нужно применить простую формулу:

newValue = int(oldValue * levels) / levels

В итоге из-за округления мы получим дискретный шаг который зависит от величины levels. С ограничением частоты также все просто, для этого найдем сначала количество семплов которое следует пропустить для получения нужной частоты по формуле:

numSamples = sampleRate / downSamplingFreq / 2

Нужно отметить что это число должно быть вещественное для плавной регулировки. Далее нужно просто завести счетчик семлов и периодически сравнивать его значение с numSamples, если оно больше или равно то следует прогрузить следующий семпл в выходной буфер иначе прогружать семпл из предыдущего такого прогруза. Т.к. мы будем использовать стерео обработку, то нужно иметь 2 независимых канала обработки. Из всего этого можно уже примерно накидать структуру эффекта:

Assembler Code:

struct 
    sampleRate              dd ?                ; // Частота дискретизации
    volume                  dd ?                ; // Громкость 0..1 (0..100%)
    downsampling            dd ?                ; // Частота среза 0..1 (0..SampleRate)
    quantize                dd ?                ; // Битность 0..1 (2 ^ (value * 15 + 1))
    lValue                  dd ?                ; // Текущее значение семпла левого канала
    rValue                  dd ?                ; // Текущее значение семпла правого канала
    sampleCounter           dd ?                ; // Счетчик семплов фильтра
ends

Теперь, если просмотреть VST SDK, то можно увидеть что VST плагин представляет собой обычную DLL которая экспортирует функцию VSTPluginMain или main (Main, MAIN, и т.д.). Хост вызывает эту функцию когда создается новый экземпляр VST эффекта. Эта функция должна при успехе возвратить указатель на объект дескриптора эффекта AEEffect, который имеет следующую структуру:

Assembler Code:

struct AEEffect
    magic                   dd ?                ; // Сигнатура 'VstP'
    dispatcher              dd ?                ; // Процедура диспечеризации
    process                 dd ?
    setParameter            dd ?                ; // Установка параметра
    getParameter            dd ?                ; // Получение параметра
    numPrograms             dd ?
    numParams               dd ?
    numInputs               dd ?                ; // Количество входных каналов
    numOutputs              dd ?                ; // Количество выходных каналов
    flags                   dd ?                ; // Флаги
    resvd1                  dd ?
    resvd2                  dd ?
    initialDelay            dd ?
    realQualities           dd ?
    offQualities            dd ?
    ioRatio                 dd ?                
    object                  dd ?                ; // Указатель на объект эффекта
    user                    dd ?
    uniqueId                dd ?                ; // Уникальный ИД эффекта
    version                 dd ?                ; // Версия эффекта
    processReplacing        dd ?                ; // Процедура обработки звука
    processDoubleReplacing  dd ?
    future                  db 56 dup (?)
ends

Как видно структура содержит множество полей, но нас интересуют только некоторые. Самое важное поле это dispatcher - указатель на функцию которая принимает различные запросы от хоста (чем-то похоже на WindowProc); setParameter/getParameter - задают указатели на функции установки/получения параметров от элементов управления или автоматизации. В numInputs/numOutputs мы задаем количество поддерживаемых каналов, в нашем случае 2. Поле object - содержит указатель на связанный пользовательский объект эффекта, т.е. там мы будем хранить указатель на структуру объекта что мы привели ранее. processReplacing и processDoubleReplacing содержат процедуры обработки звуковых данных для 32-float и 64-double соответственно. Для нашего примера мы будем использовать только 32-float Обработку. Флаги задают некоторые характеристики эффекта, мы будем использовать два значения: effFlagsCanReplacing и effFlagsNoSoundInStop. Первый говорит нам что плагин имеет функцию processReplacing и должен быть всегда установлен в VST 2.4 эффекте, а effFlagsNoSoundInStop что плагин ничего не делает если нет входного звука или там тишина. Итак чтобы связать AEEffect и наш эффект соберем их в одну структуру ASMCrusher которая будет олецетворять наш эффект:

Assembler Code:

; // Объект эффекта ASMCrusher
struct ASMCrusher
    ae                      AEEffect ?          ; // Базовый интерфейс AEEffect
    sampleRate              dd ?                ; // Частота дискретизации
    volume                  dd ?                ; // Громкость 0..1 (0..100%)
    downsampling            dd ?                ; // Частота среза 0..1 (0..SampleRate)
    quantize                dd ?                ; // Битность 0..1 (2 ^ (value * 15 + 1))
    lValue                  dd ?                ; // Текущее значение семпла левого канала
    rValue                  dd ?                ; // Текущее значение семпла правого канала
    sampleCounter           dd ?                ; // Счетчик семплов фильтра
ends

Итак для начала зададим формат файла, декларации типов и констант, импорт, экспорт и зададим релокации:

Assembler Code:

format PE GUI 4.0 DLL at 11000000h
 
include 'win32wx.inc'
 
; // Базовый интерфейс VST эффекта
struct AEEffect
    magic                   dd ?                ; // Сигнатура 'VstP'
    dispatcher              dd ?                ; // Процедура диспечеризации
    process                 dd ?
    setParameter            dd ?                ; // Установка параметра
    getParameter            dd ?                ; // Получение параметра
    numPrograms             dd ?
    numParams               dd ?
    numInputs               dd ?                ; // Количество входных каналов
    numOutputs              dd ?                ; // Количество выходных каналов
    flags                   dd ?                ; // Флаги
    resvd1                  dd ?
    resvd2                  dd ?
    initialDelay            dd ?
    realQualities           dd ?
    offQualities            dd ?
    ioRatio                 dd ?
    object                  dd ?                ; // Указатель на объект эффекта
    user                    dd ?
    uniqueId                dd ?                ; // Уникальный ИД эффекта
    version                 dd ?                ; // Версия эффекта
    processReplacing        dd ?                ; // Процедура обработки звука
    processDoubleReplacing  dd ?
    future                  db 56 dup (?)
ends
 
; // Объект эффекта ASMCrusher
struct ASMCrusher
    ae                      AEEffect ?          ; // Базовый интерфейс AEEffect
    sampleRate              dd ?                ; // Частота дискретизации
    volume                  dd ?                ; // Громкость 0..1 (0..100%)
    downsampling            dd ?                ; // Частота среза 0..1 (0..SampleRate)
    quantize                dd ?                ; // Битность 0..1 (2 ^ (value * 15 + 1))
    lValue                  dd ?                ; // Текущее значение семпла левого канала
    rValue                  dd ?                ; // Текущее значение семпла правого канала
    sampleCounter           dd ?                ; // Счетчик семплов фильтра
ends
 
NUMBER_OF_PARAMETERS    = 3                     ; // Количество параметров эффекта
UNIQUE_ID               = 1234567               ; // Уникальный ИД эффекта
VERSION                 = 1                     ; // Версия эффекта
PAR_VOLUME              = 0                     ; // Индексы параметров ...
PAR_DOWNSAMPLING        = 1
PAR_QUANTIZE            = 2
 
kEffectMagic            = 0x56737450            ; // Сигнатура AEEffect
audioMasterVersion      = 1                     ; // Версия хоста
 
; // Максимальные размеры строк
kVstMaxParamStrLen      = 8
kVstMaxVendorStrLen     = 64
kVstMaxProductStrLen    = 64
kVstMaxEffectNameLen    = 32
 
effClose                = 1                     ; // Событие вызывается когда эффект уничтожается
effSetSampleRate        = 10                    ; // Событие установки частоты дискретизации
effGetParamName         = 8                     ; // Событие получения имени параметра
effGetParamLabel        = 6                     ; // Событие получения метки параметра
effGetParamDisplay      = 7                     ; // Событие получения метки значения параметра
effGetEffectName        = 45                    ; // Событие получения имени эффекта
effGetVendorString      = 47                    ; // Событие получения имени производителя
effGetProductString     = 48                    ; // Событие получения имени продукта
effGetVendorVersion     = 49                    ; // Событие получения версии
 
effFlagsCanReplacing    = 16
effFlagsNoSoundInStop   = 512
 
section '.idata' import data readable writeable
 
library kernel, 'kernel32.dll', \
        msvcrt, 'msvcrt.dll'
 
import kernel,\
       GetProcessHeap, 'GetProcessHeap', \
       HeapAlloc, 'HeapAlloc', \
       HeapFree, 'HeapFree', \
       lstrcpynA, 'lstrcpynA'
 
import msvcrt, \
       sprintf, 'sprintf'
 
data export
export 'AsmCrusher.DLL', Main, 'Main'
end data
 
section '.reloc' data readable discardable fixups

Одной замечательной особенностью VST стандарта является то что можно вообще не реализовывать пользовательский интерфейс, нужно лишь сообщить хосту количество параметров и их свойства и каждый хост сам предоставит нужные регуляторы и свяжет их с параметрами эффекта. Поэтому далее задаем таблицу строк и список указателей на необходимые строки для каждого параметра, а также точку входа DLL. Таблицу разместим в секции .text:

Assembler Code:

section '.text' code readable executable
 
EFFECT_NAME      db      'ASMCrusher', 0
VENDOR_NAME      db      'Кривоус Анатолий Анатольевич (The trick)', 0
PRODUCT_NAME     db      'ASMCrusher', 0
PARAM_NAME_1     db      'Volume', 0
PARAM_NAME_2     db      'Frequency', 0
PARAM_NAME_3     db      'Quantize', 0
PARAM_LABEL_1    db      '%', 0
PARAM_LABEL_2    db      'Hz', 0
PARAM_LABEL_3    db      'Levels', 0
PARAM_FORMAT_1   db      '%d%%', 0
PARAM_FORMAT_2   db      '%dHz', 0
PARAM_FORMAT_3   db      '%d', 0
 
PARAMS_LIST      dd      PARAM_NAME_1, PARAM_NAME_2, PARAM_NAME_3       ; // Имена параметров
LABELS_LIST      dd      PARAM_LABEL_1, PARAM_LABEL_2, PARAM_LABEL_3    ; // Метки единиц измерения параметров
FORMATS_LIST     dd      PARAM_FORMAT_1, PARAM_FORMAT_2, PARAM_FORMAT_3 ; // Форматы параметров
 
entry EntryPoint
 
; // Точка входа DLL
proc EntryPoint, hinstDLL, fdwReason, lpvReserved
    mov eax, 1
    ret
endp

В PARAMS_LIST мы храним указатели на строки имен параметров, в LABELS_LIST на соответствующие единицы измерений для них, а в FORMATS_LIST строки формата для функции sprintf. Каждый экземпляр объекта мы будем хранить в куче процесса, для выделения и освобождения памяти в ней создадим две процедуры:

Assembler Code:

; // Выделить память
proc MemAlloc, size
    invoke HeapAlloc, <invoke GetProcessHeap>, HEAP_NO_SERIALIZE OR HEAP_ZERO_MEMORY, [size]
    ret
endp
 
; // Освободить память
proc MemFree, pMem
    invoke HeapFree, <invoke GetProcessHeap>, [pMem], HEAP_NO_SERIALIZE
    ret
endp

Теперь можно приступать к непосредственно к реализации стандартных функций VST формата. Первая самая важная функция которую мы также будем экспортировать из DLL будет Main. В ней мы сначала проверяем версию VST хоста, и если она не равна нулю то переходим к созданию эффекта. Создание эффекта - это просто выделение памяти под структуру ASMCrusher и заполнение некоторых ее полей, а также установка свойств по умолчанию:

Assembler Code:

; // Вызывается при создании нового экземпляра VST эффекта
proc Main c audioMaster
 
    ; // Проверяем версию
    cinvoke audioMaster, 0, audioMasterVersion, 0, 0, 0, 0
    .if eax = 0
        ret
    .endif
 
    stdcall CreateASMCrusher
 
    ret
 
endp
 
; // Создать объект ASMCrusher
proc CreateASMCrusher uses ebx
 
    stdcall MemAlloc, sizeof.ASMCrusher
 
    .if eax = 0
        ret
    .endif
 
    mov ebx, eax
    lea eax, [ebx + ASMCrusher.ae]
 
    mov [eax + ASMCrusher.ae.magic], kEffectMagic
    mov [eax + ASMCrusher.ae.dispatcher], Dispatcher
    mov [eax + ASMCrusher.ae.setParameter], SetParameter
    mov [eax + ASMCrusher.ae.getParameter], GetParameter
    mov [eax + ASMCrusher.ae.processReplacing], ProcessReplacing
    mov [eax + ASMCrusher.ae.numInputs], 2
    mov [eax + ASMCrusher.ae.numOutputs], 2
    mov [eax + ASMCrusher.ae.numParams], NUMBER_OF_PARAMETERS
    mov [eax + ASMCrusher.ae.flags], effFlagsCanReplacing OR effFlagsNoSoundInStop
    mov [eax + ASMCrusher.ae.uniqueId], UNIQUE_ID
    mov [eax + ASMCrusher.ae.version], VERSION
    mov [eax + ASMCrusher.ae.object], ebx
 
    ; // Загрузка значений по умолчанию
    mov [eax + ASMCrusher.sampleRate], 44100
    mov [eax + ASMCrusher.volume], 1.0
    mov [eax + ASMCrusher.downsampling], 1.0
    mov [eax + ASMCrusher.quantize], 1.0
    mov [eax + ASMCrusher.lValue], 0.0
    mov [eax + ASMCrusher.rValue], 0.0
    mov [eax + ASMCrusher.sampleCounter], 0.0
 
    mov eax, ebx
 
    ret
 
endp

В качестве параметра функция Main принимает указатель на функцию обратного вызова audioMaster, которую мы вызываем для того чтобы определить версию хоста. При создании объекта сначала выделяется память и заполняется члены базового интерфейса AEEffect, затем заполняются поля значений по умолчанию. Dispatcher, SetParameter, GetParameter, ProcessReplacing являются указателями на функции которые будут рассмотрены далее. Следующей важной функцией является функция диспетчеризации - Dispatcher, которая принимает различные события от хоста:

Assembler Code:

; // Процедура диспетчеризации
proc Dispatcher c, pEffect, uOpcode, uIndex, value, lpPtr, opt
 
    mov ecx, [pEffect]
    mov ecx, [ecx + AEEffect.object]
 
    .if [uOpcode] = effClose
        ; // Удалить VST эффект
        stdcall MemFree, ecx
        xor eax, eax
    .elseif [uOpcode] = effSetSampleRate
        ; // Установить частоту дискретизации
        mov eax, [opt]
        mov [ecx + ASMCrusher.sampleRate], eax
        xor eax, eax
    .elseif [uOpcode] = effGetParamName
        ; // Получить имя параметра
        mov eax, [uIndex]
        invoke lstrcpynA, [lpPtr], [PARAMS_LIST + eax * 4], kVstMaxParamStrLen
        xor eax, eax
    .elseif [uOpcode] = effGetParamLabel
        ; // Получить имя параметра в окне (надпись)
        mov eax, [uIndex]
        invoke lstrcpynA, [lpPtr], [PARAMS_LIST + eax * 4], kVstMaxParamStrLen
        xor eax, eax
    .elseif [uOpcode] = effGetEffectName
        ; // Получить имя эффекта
        invoke lstrcpynA, [lpPtr], EFFECT_NAME, kVstMaxEffectNameLen
        xor eax, eax
    .elseif [uOpcode] = effGetVendorString
        ; // Получить имя производителя
        invoke lstrcpynA, [lpPtr], VENDOR_NAME, kVstMaxVendorStrLen
        xor eax, eax
    .elseif [uOpcode] = effGetProductString
        ; // Получить имя продукта
        invoke lstrcpynA, [lpPtr], PRODUCT_NAME, kVstMaxProductStrLen
        xor eax, eax
    .elseif [uOpcode] = effGetVendorVersion
        ; // Получить версию
        mov eax, VERSION
    .elseif [uOpcode] = effGetParamDisplay
        ; // Получить значение параметра (надпись)
        .if [uIndex] = PAR_VOLUME
 
            ; // volume * 100
            mov eax, 100.0
            movd xmm0, eax
            mulss xmm0, [ecx + ASMCrusher.volume]
            cvtss2si eax, xmm0
 
            cinvoke sprintf, [lpPtr], [FORMATS_LIST + PAR_VOLUME * 4], eax
 
        .elseif [uIndex] = PAR_DOWNSAMPLING
 
            stdcall CalcDownsamplingFreq, [ecx + ASMCrusher.sampleRate], [ecx + ASMCrusher.downsampling]
            cinvoke sprintf, [lpPtr], [FORMATS_LIST + PAR_DOWNSAMPLING * 4], eax
 
        .elseif [uIndex] = PAR_QUANTIZE
 
            stdcall CalcLevels, [ecx + ASMCrusher.quantize]
            cinvoke sprintf, [lpPtr], [FORMATS_LIST + PAR_QUANTIZE * 4], eax
 
        .endif
 
        xor eax, eax
    .else
        xor eax, eax
    .endif
 
    ret
 
endp

Процедура диспетчеризации принимает несколько параметров, в качестве pEffect передается указатель на AEEffect нашего VST эффекта. В параметре uOpcode передается идентификатор события. uIndex содержит индексный параметр, в нашем случае здесь содержится индекс параметра о котором хост желает получить те или иные сведения. Параметр value и opt содержат целочисленные значения специфичные для события, в параметре lpPtr передается указатель на данные также специфичные для события. Анализируя исходный код видим что процедура состоит из большого switch в котором перебираются идентификаторы события. При получении события effClose мы просто освобождаем память выделенную для нашего объекта. При получении события effSetSampleRate мы устанавливаем частоту дискретизации, которая используется в расчетах; параметр opt содержит float значение частоты дискретизации. События effGetParamName и effGetParamLabel извлекают данные из таблицы строк и записывают данные в выходной параметр lpPtr. Стоит отметить что длина строки ограничена kVstMaxParamStrLen символами. Аналогично effGetEffectName, effGetVendorString, effGetProductString извлекают соответствующие данные из таблиц строк. effGetVendorVersion просто возвращает версию. При получении события effGetParamDisplay мы уже анализируем индекс эффекта, для того чтобы привести значения из логического диапазона 0..1 в реальный текстового вида, который используется в качестве надписи на элементах управления VST. Если это регулятор громкости то мы просто умножаем это число на 100 и добавляем знак процента; если это частота то мы вызываем функцию CalcDownsamplingFreq которая преобразует частоту из диапазона 0..1 в диапазон 0Гц..SampleRate/2, далее формируется строка с добавлением смволов Hz; наконец если это регулятор квантования то вызывается функция CalcLevels которая возвращает количество уровней исходя из диапазона 0..1 (2..65536). Давайте рассмотрим исходный код этих функций:

Assembler Code:

; // Получить реальную частоту ресемплинга на основании значения downsampling
; // Вычисляем по формуле int(downsampling * samplerate * 0.5)
proc CalcDownsamplingFreq, sampleRate, downsampling
 
    mov eax, 0.5
    movd xmm0, eax
    mulss xmm0, [downsampling]
    mulss xmm0, [sampleRate]
    cvtss2si eax, xmm0
 
    ret
 
endp
 
; // Посчитать количество уровней сигнала на основании значения quantize
; // Вычисляем по формуле int(2 ^ (quantize * 15 + 1)))
proc CalcLevels, quantize
 
    mov eax, 2
    mov ecx, 15.0
    movss xmm0, [quantize]
    movd xmm1, ecx
    mulss xmm0, xmm1
    cvtss2si ecx, xmm0
    shl eax, cl
 
    ret
 
endp

Первая функция вычисляет частоту по формуле int(downsampling * samplerate * 0.5), где downsampling находится в диапазоне [0..1]. Вторая функция получает количество уровней сигнала по формуле int(2^{quantize * 15 + 1}), где quantize также располагается в диапазоне [0..1]. Эта функция оперирует 16 битными значениями, т.е. максимум получается 65536, а минимум 2. Далее рассмотрим функцию установки и получения параметров:

Assembler Code:

; // Получить параметр
proc GetParameter c, pEffect, uIndex
 
    mov ecx, [pEffect]
    mov ecx, [ecx + AEEffect.object]
 
    .if [uIndex] = PAR_VOLUME
        fld [ecx + ASMCrusher.volume]
    .elseif [uIndex] = PAR_DOWNSAMPLING
        fld [ecx + ASMCrusher.downsampling]
    .elseif [uIndex] = PAR_QUANTIZE
        fld [ecx + ASMCrusher.quantize]
    .else
        fldz
    .endif
 
    ret
endp
 
; // Установить параметр
proc SetParameter c, pEffect, uIndex, fValue
 
    mov ecx, [pEffect]
    mov ecx, [ecx + AEEffect.object]
    mov eax, dword [fValue]
 
    .if [uIndex] = PAR_VOLUME
        mov [ecx + ASMCrusher.volume], eax
    .elseif [uIndex] = PAR_DOWNSAMPLING
        mov [ecx + ASMCrusher.downsampling], eax
    .elseif [uIndex] = PAR_QUANTIZE
        mov [ecx + ASMCrusher.quantize], eax
    .endif
 
    ret
 
endp

Каждый параметр в VST кодируется 32 bit - float значением в диапазоне от 0 до 1. Здесь все просто, нужно только отметить что возвращаемое значение возвращается на вершине стека FPU.
При обработке звука вызывается функция ProcessReplacing которая принимает указатель на объект, два указателя на указатели семплов и количество семплов:

Assembler Code:

proc ProcessReplacing c uses esi edi ebx, pEffect, pInputs, pOutputs, sampleFrames
 
    mov esi, [pInputs]
    mov edi, [pOutputs]
    mov ebx, [pEffect]
    mov ebx, [ebx + AEEffect.object]
 
    ; // Обрабатываем левый канал
    stdcall ApplyEffectToChannel, ebx, dword [esi], dword [edi], dword [sampleFrames], dword [ebx + ASMCrusher.lValue]
    mov [ebx + ASMCrusher.lValue], eax
 
    ; // Обрабатываем правый канал
    stdcall ApplyEffectToChannel, ebx, dword [esi + 4], dword [edi + 4], dword [sampleFrames], dword [ebx + ASMCrusher.rValue]
    mov [ebx + ASMCrusher.rValue], eax
 
    ret
 
endp

pInputs в нашем случае содержит указатель на два указателя (правый и левый каналы) на звуковые семплы в формате 32 bit float, pOutputs - тоже самое только на выходной буфер. sampleFrames содержит количество семплов в канале. В качестве процедуры обработки служит процедура ApplyEffectToChannel:

Assembler Code:

; // Применить эффект к буферу
; // Возвращает значение семпла
proc ApplyEffectToChannel uses esi edi ebx, pObject, pInput, pOutput, nCount, fValue
 
    mov ebx, [pObject]
    mov esi, [pInput]
    mov edi, [pOutput]
 
    ; // Вычисляем количество уровней
    stdcall CalcLevels, [ebx + ASMCrusher.quantize]
    cvtsi2ss xmm1, eax
 
    ; // Вычисляем количество семплов для частоты среза
    mov eax, 2.0
    movd xmm0, eax
    divss xmm0, [ebx + ASMCrusher.downsampling]
 
    ; // Восстанавливаем регистр счетчика фильтра
    movss xmm2, [ebx + ASMCrusher.sampleCounter]
 
    ; // Загружаем граничные значения
    mov eax, 1.0
    movd xmm3, eax
    mov eax, -1.0
    movd xmm4, eax
 
    ; // Загружаем значение громкости в регистр
    movss xmm6, [ebx + ASMCrusher.volume]
 
    ; // Загружаем сохраненное значение семпла и применяем уровень громкости
    movd xmm5, [fValue]
    mulss xmm5, xmm6
 
    ; // Задаем количество семплов
    mov ecx, [nCount]
 
    ; // Проход по семплам
    .PROCESS_SAMLE:
 
        ; // Увеличиваем счетчик регистра фильтра
        addss xmm2, xmm3
        comiss xmm2, xmm0
        ; // Если количество семлов превышает порог, загружаем новый
        jb .STORE_SAMPLE
 
        ; // Сравниваем с 1
        comiss xmm3, dword [esi]
        jb .SET_MAX
        ; // Сравниваем с -1
        comiss xmm4, dword [esi]
        ja .SET_MIN
        movss xmm5, dword [esi]
 
        .CALC_SAMPLE:
        ; // Сохраняем семп в регистр edx
        movd edx, xmm5
        ; // Вычисляем семпл по формуле int(sample * levels) / levels
        mulss xmm5, xmm1
        cvtss2si eax, xmm5
        cvtsi2ss xmm5, eax
        divss xmm5, xmm1
 
        ; // Изменяем громкость
        mulss xmm5, xmm6
        ; // Обновляем downsampling регистр
        subss xmm2, xmm0
 
        jmp .STORE_SAMPLE
 
        .SET_MAX:
        movss xmm5, xmm3
        jmp .CALC_SAMPLE
        .SET_MIN:
        movss xmm5, xmm4
        jmp .CALC_SAMPLE
 
        .STORE_SAMPLE:
 
        ; // Сохраняем текущий семпл
        movss dword [edi], xmm5
        add edi, 4
        add esi, 4
 
    loop .PROCESS_SAMLE
 
    ; // Сохраняем значения
    movd [ebx + ASMCrusher.sampleCounter], xmm2
 
    ; // Возвращаем значение семпла
    mov eax, edx
 
    ret
 
endp

Эта процедура работает по алгоритмам описаным выше. Стоит отметить что для ускорения большинство действий выполняются в регистрах, на выходе тоолько значения сохраняются в объект для последующего восстановления состояния. Регистр xmm0 содержит количество семплов которые необходимо повторять (удержать) чтобы получить необходимую частоту среза. xmm1 содержит количество уровней квантования. xmm3 и xmm4 содержат константы 1 и -1 которые нужны для проверки выхода за диапазон допустимых значений. xmm6 содержит текуще значение громкости, xmm5 содержит текущее значение семпла умноженное на громкость. xmm2 - счетчик семплов. edx содержит текущее значение семпла без применения умножения громкости. Остальное все понятно из кода и пиведенного в начале описания алгоритма.
Все, пробуем компилировать, и если все выполнено без ошибок в папке с исходником появится DLL. Эту DLL можно теперь подключать к любому хосту. Здесь я приведу несколько примеров GUI хостов:

Исходник прикреплен к сообщению. Всем спасибо за внимание!
С уважением,
Кривоус Анатолий (The trick).